F#は.NET Framework上で動作する新たな言語で、Visual Studio 2010から標準搭載されます。F#は基本的には関数型言語と呼ばれる種類の言語ですが、オブジェクト指向プログラミングや命令型(手続き型)プログラミングもサポートしているため、関数型言語がベースのマルチパラダイム言語といったほうが適切です。また、さまざまな近代的な関数型プログラミングの機能を備えており、関数型プログラマから注目を集めているモナド構文もサポートしています。

F#はObjective Caml(OCaml)というフランスの国立研究機関が開発した言語を元に作られました。したがって、基本的な文法はOCamlと同じで、一部の機能を除けばそのままコンパイル可能です。しかしF#では、OCamlの文法を簡略化した軽量構文(lightweight syntax)という文法が推奨され、こちらが基本的な文法となります。

F#には、他のVisual StudioファミリーのC#やVB.NETにはない大きな特徴があります。それはインタプリタの存在です。インタプリタとは、コマンドプロンプトなどのようにコンソール上から直接プログラムコードを入力して実行できる環境です。C#やVB.NETは基本的にソースコードをコンパイルして、生成された実行可能ファイルを実行するという手順を踏みます。F#も当然コンパイルして実行可能ファイルを生成することができますが、同時にインタプリタも提供しています。インタプリタを使うと、プログラムコードを入力するたびに応答が得られるので、さまざまなコードを試したりするのに非常に向いています。たとえば、ウィンドウを生成して実際に画面上にウィンドウを出したまま、そのウィンドウのプロパティをいろいろ変化させるといったことが可能です。

ここではF#の環境のインストールと起動方法について説明します。

このサイトでは、基本的にF#インタプリタを用いて解説をしていきます。F#インタプリタには、コンソール版とVisual Studio版の2種類があります。コンソール版はコマンドプロンプト上で動作する対話モードで、Visual Studio版はVisual Studio内の子ウィンドウとして動作します。

基本的にはどちらを使ってもいいのですが、ここではVisual Studio版を使うことをお勧めします。Visual Studio版を使うと、Visual Studio上のソースコードエディタ上でF#のコードを選択してAlt+Enterを押すことで、その選択範囲内のコードをF#インタプリタに送ることができ、タイプミスした場合のやり直しが容易にできます。また、現在のバージョン(Visual Studio 2010 beta 1; v1.9.6.16)のコンソール版では、F#インタプリタ自体が2バイト文字をきちんと処理していないため、ひらがなや漢字の入力ができないという問題があります。

ここでF#インタプリタを使って、F#に少し簡単に触れてみましょう。まずは定番のHello, world!からです。

F# Version 1.9.6.2, compiling for .NET Framework Version v2.0.50727

Please send bug reports to fsbugs@microsoft.com
For help type #help;;

> printf "Hello, world!\n";;
Hello, world!
val it : unit = ()

> printfn "Hello, world!";; // 行末で改行
Hello, world!
val it : unit = ()

> open System.Windows.Forms;; // 名前空間を開く
> MessageBox.Show("Hello, world!");;　// Windows Formsのメッセージボックスを呼び出す
val it : DialogResult = OK

> System.Windows.Forms.MessageBox.Show("Hello, world!");; // 完全修飾名で呼び出す
val it : DialogResult = OK

> System.IO.Directory.GetCurrentDirectory();;
val it : string = "c:\\Program Files\\Microsoft Visual Studio 9.0\\Common7\\IDE"

F#インタプリタでは、入力の完了として入力の最後に;;というセミコロンを2つ続けたものを入力します。したがって、単なる改行記号は入力の完了ではないので注意してください。

本サイトでは、ユーザがF#インタプリタ上に対して入力する文字列を「入力」と呼び、色つきのフォントで表します。また、ユーザの入力に対して、F#インタプリタが返す文字列を「応答」と呼びます。上の例では、val itから始まる行が F#からの応答となります(Hello, world!の文字列はF#インタプリタ自体が返した応答ではなく、自分が入力したプログラムが出力した文字列なので注意してください)。

コンソールに文字を出力するには、printf関数を使います。printfn関数を使うと行末で自動的に改行してくれます。メッセージボックスを表示するには、まずWindows Formsの名前空間を開き、MessageBoxクラスのShow静的メソッドを呼び出します。また、次の入力のように完全修飾名で呼び出すこともできます。同様にして、C#でもお馴染みの他の.NETのクラスも利用することができます。

上の入力例においてval itではじまる行は、その直前の入力を実行した結果の値を意味します。F#インタプリタでは、実行結果の値は自動的にitという変数に割り当てられます。printfおよびprintfnの戻り値はunit型というもので、ちょうどvoidに相当するものです。MessageBox.Showの結果はDialogResult値が返ってきています。

単一行のコメントは//というスラッシュを2つつづけたもののあとに書くことができ、複数行のコメントは(*と*)で囲われた部分に書くことができます。

次に簡単な計算をやってみましょう。

> 3;;
val it : int = 3
> 3 + 5;;
val it : int = 8
> (3 + 2) * 5 / 10;;
val it : int = 2

変数への代入は、以下のようにletを使います。

> let x = 3;;
val x : int

> let y = 5;;
val y : int

> x + y;;
val it : int = 8

入力の直後にvalに続けて変数名とその型が表示されていることがわかります。 ちなみに後で詳しく説明しますが、このサイトではこれらを変数とは呼ばず識別子という呼び方をします。

関数は以下のように定義し、C#のように引数全体を括弧で囲む必要は基本的にありません。

> let plus x y = x + y;;
val plus : int -> int -> int

> plus 3 2;;
val it : int = 5

ここで少し注目してもらいたいのが、先ほどの変数(識別子)の定義のときも関数の定義と同様にletを使っていることです。ここが関数型言語としての特徴で、値と関数を同じように扱うことができます。実際、関数も関数値という値として扱われ、ふつうの値のように簡単に代入したり、引数として渡したり、戻り値として返したりすることができます。

> let plus2 = plus;; // 関数を別の変数(識別子)に代入
val plus2 : (int -> int -> int)

> plus2 5 3;;
val it : int = 8

ここまでに紹介したのはごく一般的な機能ですが、ここでF#の特徴的な機能をいくつか紹介しておきましょう。

まずは計量単位(units of measure)です。これは物理でいう次元解析に相当するもので、たとえば値にメートルやグラムなどの単位情報を付加し、誤って違う単位同士を足してしまったりする間違いを防ぐことができます。

> [<Measure>] type kg;; // 体重の単位
[<Measure>]
type kg

> [<Measure>] type m;; // 身長の単位
[<Measure>]
type m

> [<Measure>] type BMI = kg / m^2;; // BMI指数の単位
[<Measure>]
type BMI = kg/m ^ 2

> let weight = 50.0<kg>;; // 体重
val weight : float<kg>

> let tall = 1.60<m>;; // 身長
val tall : float<m>

> let bmi = weight / (tall*tall);; // BMI指数を計算
val bmi : float<kg/m ^ 2>

> let standard_BMI = 22.0<BMI>;; // 標準BMI指数
val standard_BMI : float<BMI>

> standard_BMI < bmi;; // 標準BMI指数との比較
val it : bool = false

> standard_BMI < tall;; // 標準BMI指数と身長の比較(単位が違うのでエラー)
  standard_BMI < tall;;
  ---------------^^^^^

stdin(45,16): error FS0001: Type mismatch. Expecting a
  float<BMI>
but given a
  float<m>.
The unit of measure 'BMI' does not match the unit of measure 'm'

次に紹介するのはシーケンス式(sequence expression)です。これを使うと規則的な数列やデータ列を簡単に作り出すことができます。

> [ 1..10 ];;
val it : int list = [1; 2; 3; 4; 5; 6; 7; 8; 9; 10]

> [ for x in [ 1..5 ] -> x ];;
val it : int list = [1; 2; 3; 4; 5]

> [ for x in [ 1..5 ] -> x * 2 ];;
val it : int list = [2; 4; 6; 8; 10]

> [ for x in [ 1..5 ] ->
    [ for y in [ 1..x ] -> (x,y) ]
  ];;
val it : (int * int) list list
= [[(1, 1)]; [(2, 1); (2, 2)]; [(3, 1); (3, 2); (3, 3)];
   [(4, 1); (4, 2); (4, 3); (4, 4)]; [(5, 1); (5, 2); (5, 3); (5, 4); (5, 5)]]

実はこのシーケンス式の背景には、モナド(monad)という概念が隠れています。F#にはワークフローというモナド構文が存在し、シーケンス式はそれを用いて実装された機能なのです。F#ではほかにも、マルチスレッドを扱うのに特化した非同期ワークフロー(asynchronous workflow)や、構文解析を行うライブラリのFParsecがワークフローを用いて実装されています。